Ultrasonic sensor

Parallax PING range finder este un sensor ultrasonic capabil sa detecteze obiecte aflate pana la distanta de 3 metri.
Sensorul are doi pini dedicati alimentarii (GND si VCC), iar al treilea pin este folosit si pentru input si output.

Pin-ul dedicat citirii datelor trebuie sa faca un shifting de la modul output la modul input. Pentru inceput noi trebuie sa trimitem un puls, dupa care platforma Arduino comuta pin-ul pe modul input si asteapta sa receptioneze sunetul ecou folosind functia pulseIn(). Duratia pulsului este egala cu timpul efectuat de ultrasunet pentru a ajunge la obiect, si de la obiect inapoi la sensor.

Folosind viteza sunetului, putem calcula din timp distanta.

Lucruri necesare

1. Platforma Arduino
2. Sensor Ultrasonic Parallax
3. Cablu de conexiuni/breadboard

Creeare circuitului

Conectati pinul 5V la pinul 5V de pe platforma Arduino.

GND-ul la GND-ul de pe platforma Arduino.

Iar pin-ul de semnal la pin-ul 7 PWM.

Exemplu de cod

const int pingPin = 7;

void setup() {
  Serial.begin(9600);
}

void loop()
{
  // establish variables for duration of the ping, 
  // and the distance result in inches and centimeters:
  long duration, inches, cm;

  // The PING))) is triggered by a HIGH pulse of 2 or more microseconds.
  // Give a short LOW pulse beforehand to ensure a clean HIGH pulse:
  pinMode(pingPin, OUTPUT);
  digitalWrite(pingPin, LOW);
  delayMicroseconds(2);
  digitalWrite(pingPin, HIGH);
  delayMicroseconds(5);
  digitalWrite(pingPin, LOW);

  // The same pin is used to read the signal from the PING))): a HIGH
  // pulse whose duration is the time (in microseconds) from the sending
  // of the ping to the reception of its echo off of an object.
  pinMode(pingPin, INPUT);
  duration = pulseIn(pingPin, HIGH);

  // convert the time into a distance
  inches = microsecondsToInches(duration);
  cm = microsecondsToCentimeters(duration);
  
  Serial.print(inches);
  Serial.print("in, ");
  Serial.print(cm);
  Serial.print("cm");
  Serial.println();
  
  delay(100);
}

long microsecondsToInches(long microseconds)
{
  // According to Parallax's datasheet for the PING))), there are
  // 73.746 microseconds per inch (i.e. sound travels at 1130 feet per
  // second).  This gives the distance travelled by the ping, outbound
  // and return, so we divide by 2 to get the distance of the obstacle.
  // See: http://www.parallax.com/dl/docs/prod/acc/28015-PING-v1.3.pdf
  return microseconds / 74 / 2;
}

long microsecondsToCentimeters(long microseconds)
{
  // The speed of sound is 340 m/s or 29 microseconds per centimeter.
  // The ping travels out and back, so to find the distance of the
  // object we take half of the distance travelled.
  return microseconds / 29 / 2;
}

Acum, cu acest senzor pot fi create o multime de aplicatii. (robot avoiding wall, magnet-like electromagnet etc)


ENjoy!...